fixing gitignore

lisp/recently-updated.el

@@ -0,0 +1,113 @@
+;;; recently-updated.el --- Generate recently-updated.org  -*- lexical-binding: t; -*-
+
+(require 'cl-lib)
+(require 'org)
+
+(defvar z-org-root
+  (file-name-as-directory
+   (expand-file-name "~/master-folder/org_files/org_web"))
+  "Root directory of the Org source files.")
+
+;; Which Org files should be skipped for Recently Updated
+(defun z/recent-omit-org-p (rel-org)
+  "Return non-nil if REL-ORG (relative to `z-org-root`) should not be listed."
+  (let* ((name (file-name-nondirectory rel-org)))
+    (or
+     ;; assets-ish / tags
+     (string-prefix-p "assets/" rel-org)
+     (string-match-p "/assets/" rel-org)
+     (string-prefix-p "tags/" rel-org)
+     (string-match-p "/tags/" rel-org)
+
+     ;; generated/meta orgs
+     (member name '("sitemap.org"
+                    "categories.org"
+                    "recently-updated.org"
+		    "wip.org"
+		    ))
+
+     ;; any *-list.org sitemaps (posts-list.org, blogs-list.org, etc.)
+     (string-match-p "-list\\.org\\'" name))))
+
+(defun z/read-org-title+mtime (file)
+  "Return (TITLE . MTIME) for Org FILE.
+
+TITLE from #+TITLE or file name.
+MTIME is the file's modification time (real 'last updated')."
+  (with-temp-buffer
+    (insert-file-contents file)
+    (org-mode)
+    (let* ((props (org-collect-keywords '("TITLE")))
+           (title-cell (assoc "TITLE" props))
+           (title (or (and title-cell
+                           (car (cdr title-cell)))
+                      (file-name-base file)))
+           (mtime (nth 5 (file-attributes file))))
+      (cons title mtime))))
+
+
+(defun z/read-org-title+date (file)
+  "Return (TITLE . TIME) for Org FILE.
+
+TITLE:
+- from #+TITLE, or file-name if missing.
+
+TIME:
+- from #+DATE if parseable as an org time string,
+- otherwise from file's modification time."
+  (with-temp-buffer
+    (insert-file-contents file)
+    (org-mode)
+    (let* ((props (org-collect-keywords '("TITLE" "DATE")))
+           ;; TITLE
+           (title-cell (assoc "TITLE" props))
+           (title (or (and title-cell
+                           (car (cdr title-cell)))
+                      (file-name-base file)))
+           ;; DATE
+           (date-cell (assoc "DATE" props))
+           (date-str (and date-cell
+                          (car (cdr date-cell))))
+           (time (or (and date-str
+                          (ignore-errors
+                            (org-time-string-to-time date-str)))
+                     (nth 5 (file-attributes file)))))
+      (cons title time))))
+
+(defun z/generate-recently-updated-org (&optional n)
+  "Generate recently-updated.org in `z-org-root`.
+
+Lists top N most recently updated Org pages
+(excluding tags, sitemaps, *-list.org, etc).
+Defaults to N=30."
+  (let* ((count (or n 30))
+         (org-files (directory-files-recursively z-org-root "\\.org\\'"))
+         (items '()))
+    ;; Collect (REL PATH, TITLE, TIME)
+    (dolist (full org-files)
+      (let ((rel (file-relative-name full z-org-root)))
+        (unless (z/recent-omit-org-p rel)
+          (pcase-let* ((`(,title . ,time) (z/read-org-title+mtime full)))
+            (push (list rel title time) items)))))
+    ;; Sort newest first by TIME
+    (setq items
+          (sort items
+                (lambda (a b)
+                  (time-less-p (nth 2 b) (nth 2 a)))))
+    ;; Trim
+    (setq items (cl-subseq items 0 (min count (length items))))
+    ;; Write Org file
+    (with-temp-file (expand-file-name "recently-updated.org" z-org-root)
+      (insert "#+TITLE: Recently Updated\n"
+              "#+OPTIONS: toc:nil num:nil\n\n"
+              "* Recently Updated (top 26 files - per lima's request)\n")
+      (dolist (it items)
+        (let* ((rel   (nth 0 it))
+               (title (nth 1 it))
+               (time  (nth 2 it))
+               (datestr (format-time-string "%Y-%m-%d %H:%M" time)))
+          (insert (format "- [[file:%s][%s]] @@html:<span class=\"post-date\">%s</span>@@\n"
+                          rel title datestr))))))
+  (message "Wrote recently-updated.org"))
+
+(provide 'recently-updated)

lisp/sidenotes.el

@@ -0,0 +1,26 @@
+(defun z/no-sidenotes-file-p (file)
+  "Return non-nil if FILE should be rendered without sidenotes.
+
+A file is no-sidenotes if:
+  - It has a #+NO_SIDENOTES: keyword, or
+  - Its FILETAGS contain :NO_SIDENOTES: or :KANBAN:, or
+  - Any top-level heading contains \"KANBAN\"."
+  (when (file-exists-p file)
+    (with-temp-buffer
+      (insert-file-contents file)
+      (org-mode)
+      (let* ((case-fold-search t)
+             (keywords (org-collect-keywords
+                        '("NO_SIDENOTES" "FILETAGS")))
+             (flag     (cadr (assoc "NO_SIDENOTES" keywords)))
+             (filetags (cadr (assoc "FILETAGS" keywords))))
+        (or
+         (and flag (string-match-p "\\S-" flag))
+         (and filetags
+              (string-match-p
+               ":\\(NO_SIDENOTES\\|KANBAN\\):"
+               (concat ":" filetags ":")))
+         (save-excursion
+           (goto-char (point-min))
+           (re-search-forward "^\\*+ .*KANBAN.*" nil t)))))))
+(provide 'sidenotes)

lisp/sitemaps.el

@@ -0,0 +1,341 @@
+(defun z/posts-sitemap (title list)
+  "sitemap that lists post links as bullet points with dates and tags."
+  (concat
+   "#+TITLE: " title "\n"
+   "#+OPTIONS: toc:nil num:nil \n\n"
+   "See the categories: @@html:<a href=\"../categories.html\">Categories</a>@@\n\n"
+   "* Posts:\n"
+   (mapconcat
+    (lambda (entry)
+      (let* ((link (car entry))
+             ;; extract relative file name from the link
+             (filename (if (string-match "\\[\\[file:\\([^]]+\\)\\]" link)
+                           (match-string 1 link)
+                         link))
+             (full-path (expand-file-name filename "~/master-folder/org_files/org_web/posts/"))
+             (date-str "no date")
+             (tags-str ""))
+        ;; Get publish date
+        (let ((date (org-publish-find-date full-path org-publish-project-alist)))
+          (when date
+            (setq date-str (format-time-string "%d-%m-%Y %H:%M" date))))
+        ;; Get FILETAGS from file buffer
+        (when (file-exists-p full-path)
+          (with-temp-buffer
+            (insert-file-contents full-path)
+            (org-mode)
+            (let* ((tags (cadr (assoc "FILETAGS" (org-collect-keywords '("FILETAGS"))))))
+              (when tags
+                (setq tags-str (mapconcat (lambda (tag)
+					    (format "@@html:<a href=\"/tags/%s.html\"> <span class=\"post-tag\">%s</span> </a>@@" tag tag))
+                                          (split-string tags ":" t)  ;; <- Splits by ":" and removes empty strings
+                                          " "))))))
+        ;; Final line output
+        (format "- %s @@html:<span class=\"post-date\">%s</span>@@ %s" link date-str tags-str)))
+    (cdr list)
+    "\n")))
+
+
+(defun z/blogs-sitemap (title list)
+  "sitemap that lists blog links as bullet points with dates and tags."
+  (concat
+   "#+TITLE: " title "\n"
+   "#+OPTIONS: toc:nil num:nil \n\n"
+   "See the categories: @@html:<a href=\"../categories.html\">Categories</a>@@\n\n"
+   "* Blogs:\n"
+   (mapconcat
+    (lambda (entry)
+      (let* ((link (car entry))
+             ;; extract relative file name from the link
+             (filename (if (string-match "\\[\\[file:\\([^]]+\\)\\]" link)
+                           (match-string 1 link)
+                         link))
+             (full-path (expand-file-name filename "~/master-folder/org_files/org_web/blogs/"))
+             (date-str "no date")
+             (tags-str ""))
+        ;; Get publish date
+        (let ((date (org-publish-find-date full-path org-publish-project-alist)))
+          (when date
+            (setq date-str (format-time-string "%d-%m-%Y %H:%M" date))))
+        ;; Get FILETAGS from file buffer
+        (when (file-exists-p full-path)
+          (with-temp-buffer
+            (insert-file-contents full-path)
+            (org-mode)
+            (let* ((tags (cadr (assoc "FILETAGS" (org-collect-keywords '("FILETAGS"))))))
+              (when tags
+                (setq tags-str (mapconcat (lambda (tag)
+                                            (format "@@html:<a href=\"/tags/%s.html\"> <span class=\"post-tag\">%s</span> </a>@@" tag tag))
+                                          (split-string tags ":" t)  ;; <- Splits by ":" and removes empty strings
+                                          " "))))))
+        ;; Final line output
+        (format "- %s @@html:<span class=\"post-date\">%s</span>@@ %s" link date-str tags-str)))
+    (cdr list)
+    "\n")))
+
+
+(defun z/books-sitemap (title list)
+  "sitemap that lists books."
+  (concat
+   "#+TITLE: " title "\n"
+   "#+OPTIONS: toc:nil num:nil \n\n"
+   "See the categories: @@html:<a href=\"../categories.html\">Categories</a>@@\n\n"
+   "* Book Notes:\n"
+   (mapconcat
+    (lambda (entry)
+      (let* ((link (car entry))
+             ;; extract relative file name from the link
+             (filename (if (string-match "\\[\\[file:\\([^]]+\\)\\]" link)
+                           (match-string 1 link)
+                         link))
+             (full-path (expand-file-name filename "~/master-folder/org_files/org_web/books/"))
+             (date-str "no date")
+             (tags-str ""))
+        ;; Get publish date
+        (let ((date (org-publish-find-date full-path org-publish-project-alist)))
+          (when date
+            (setq date-str (format-time-string "%d-%m-%Y %H:%M" date))))
+        ;; Get FILETAGS from file buffer
+        (when (file-exists-p full-path)
+          (with-temp-buffer
+            (insert-file-contents full-path)
+            (org-mode)
+            (let* ((tags (cadr (assoc "FILETAGS" (org-collect-keywords '("FILETAGS"))))))
+              (when tags
+                (setq tags-str (mapconcat (lambda (tag)
+                                            (format "@@html:<a href=\"/tags/%s.html\"> <span class=\"post-tag\">%s</span> </a>@@" tag tag))
+                                          (split-string tags ":" t)  ;; <- Splits by ":" and removes empty strings
+                                          " "))))))
+        ;; Final line output
+        (format "- %s @@html:<span class=\"post-date\">%s</span>@@ %s" link date-str tags-str)))
+    (cdr list)
+    "\n")))
+
+(defun z/2025-sitemap (title list)
+  "Sitemap that lists 2025 posts grouped by month, with dates and FILETAGS."
+  (let ((output (concat
+                 "#+TITLE: " title "\n"
+                 "#+OPTIONS: toc:nil num:nil \n\n"
+                 "See the categories: @@html:<a href=\"../../categories.html\">Categories</a>@@\n\n"
+                 "* 2025\n"))
+        (current-month nil))
+
+    ;; `list` is what org-publish passes in; we skip its car (top-level title node)
+    (dolist (entry (cdr list))
+      ;; In this setup each ENTRY is usually (LINK . OTHER-STUFF)
+      (when (consp entry)
+        (let* ((link (car entry))
+               ;; Extract relative filename from the [[file:...][...]] link
+               (filename (if (string-match "\\[\\[file:\\([^]]+\\)\\]" link)
+                             (match-string 1 link)
+                           link))
+               (full-path (expand-file-name
+                           filename
+                           "~/master-folder/org_files/org_web/blogs/2025/"))
+               (date (when (file-exists-p full-path)
+                       (org-publish-find-date full-path org-publish-project-alist)))
+               (date-str (if date
+                             (format-time-string "%d-%m-%Y %H:%M" date)
+                           "no date"))
+               (month-str (if date
+                              (format-time-string "%B %Y" date) ; e.g. "August 2025"
+                            "No date"))
+               (tags-str ""))
+
+          ;; Collect FILETAGS from the file
+          (when (file-exists-p full-path)
+            (with-temp-buffer
+              (insert-file-contents full-path)
+              (org-mode)
+              (let ((tags (cadr (assoc "FILETAGS"
+                                       (org-collect-keywords '("FILETAGS"))))))
+                (when tags
+                  (setq tags-str
+                        (mapconcat
+                         (lambda (tag)
+                           (format "@@html:<a href=\"/tags/%s.html\"> \
+<span class=\"post-tag\">%s</span> </a>@@" tag tag))
+                         (split-string tags ":" t)
+                         " "))))))
+
+          ;; Insert month heading whenever month changes
+          (unless (equal month-str current-month)
+            (setq current-month month-str)
+            (setq output (concat output "\n** " month-str "\n")))
+
+          ;; Insert the actual entry
+          (setq output
+                (concat output
+                        (format "- %s @@html:<span class=\"post-date\">%s</span>@@ %s\n"
+                                link date-str tags-str))))))
+
+    output))
+
+
+(defun z/career-sitemap (title list)
+  "Sitemap that lists careers posts grouped by month, with dates and FILETAGS."
+  (let ((output (concat
+                 "#+TITLE: " title "\n"
+                 "#+OPTIONS: toc:nil num:nil \n\n"
+                 "See the categories: @@html:<a href=\"../../categories.html\">Categories</a>@@\n\n"
+                 "* 2025\n"
+		 "See the following page for more details: @@html:<a href=\"./career-intro.html\">Career Intro</a>@@\n"
+		 ))
+        (current-month nil))
+
+    ;; `list` is what org-publish passes in; we skip its car (top-level title node)
+    (dolist (entry (cdr list))
+      ;; In this setup each ENTRY is usually (LINK . OTHER-STUFF)
+      (when (consp entry)
+        (let* ((link (car entry))
+               ;; Extract relative filename from the [[file:...][...]] link
+               (filename (if (string-match "\\[\\[file:\\([^]]+\\)\\]" link)
+                             (match-string 1 link)
+                           link))
+               (full-path (expand-file-name
+                           filename
+                           "~/master-folder/org_files/org_web/posts/career/"))
+               (date (when (file-exists-p full-path)
+                       (org-publish-find-date full-path org-publish-project-alist)))
+               (date-str (if date
+                             (format-time-string "%d-%m-%Y %H:%M" date)
+                           "no date"))
+               (month-str (if date
+                              (format-time-string "%B %Y" date) ; e.g. "August 2025"
+                            "No date"))
+               (tags-str ""))
+
+          ;; Collect FILETAGS from the file
+          (when (file-exists-p full-path)
+            (with-temp-buffer
+              (insert-file-contents full-path)
+              (org-mode)
+              (let ((tags (cadr (assoc "FILETAGS"
+                                       (org-collect-keywords '("FILETAGS"))))))
+                (when tags
+                  (setq tags-str
+                        (mapconcat
+                         (lambda (tag)
+                           (format "@@html:<a href=\"/tags/%s.html\"> \
+<span class=\"post-tag\">%s</span> </a>@@" tag tag))
+                         (split-string tags ":" t)
+                         " "))))))
+
+          ;; Insert month heading whenever month changes
+          (unless (equal month-str current-month)
+            (setq current-month month-str)
+            (setq output (concat output "\n** " month-str "\n")))
+
+          ;; Insert the actual entry
+          (setq output
+                (concat output
+                        (format "- %s @@html:<span class=\"post-date\">%s</span>@@ %s\n"
+                                link date-str tags-str))))))
+
+    output))
+
+
+
+(defun z/categories-sitemap (title _list)
+  "Generate a categories page by scanning tags across org-posts and org-blogs."
+  (let* ((expanded (org-publish-expand-projects org-publish-project-alist))
+         (posts    (assoc "org-posts" expanded))
+         (blogs    (assoc "org-blogs" expanded))
+         ;; DO NOT set :exclude to "" — it excludes everything
+         (files (cl-remove-duplicates
+                 (append (and posts (org-publish-get-base-files posts))
+                         (and blogs (org-publish-get-base-files blogs)))
+                 :test #'file-equal-p))
+         ;; optional: drop the generated sitemaps
+         (files (cl-remove-if
+                 (lambda (f)
+                   (member (file-name-nondirectory f)
+                           '("posts-list.org" "blogs-list.org" "sitemap.org" "categories.org")))
+                 files))
+         (counts (make-hash-table :test 'equal)))
+    ;;(message "files I will scan: %S" files)
+    (dolist (f files)
+      (when (file-readable-p f)
+        (with-temp-buffer
+          (insert-file-contents f)
+          (org-mode)
+          (let* ((kw (org-collect-keywords '("FILETAGS" "TAGS")))
+                 (raw (car (or (cdr (assoc "FILETAGS" kw))
+                               (cdr (assoc "TAGS" kw))))))
+            (when raw
+              (dolist (tag (split-string raw ":" t))
+                (puthash tag (1+ (gethash tag counts 0)) counts)))))))
+
+    (let (tags)
+      (maphash (lambda (k _) (push k tags)) counts)
+      (setq tags (sort tags #'string-lessp))
+      (concat
+       "#+TITLE: " title "\n#+OPTIONS: toc:nil num:nil title:nil\n\n* Categories (Includes both blogs and posts)\n"
+       (if tags
+	   (mapconcat
+	    (lambda (tag)
+	      (format "- [[file:tags/%s.org][@@html:<span class=\"post-tag\">%s</span>@@]] (%d)"
+		      (z/tag-slug tag) tag (gethash tag counts))
+	      )
+	    tags
+	    "\n")
+         "_No tags found yet._")))))
+
+(defun z/wip-file-p (file)
+  "Return non-nil if FILE should be treated as WIP.
+A file is WIP if:
+  - It has a #+WIP: keyword with any non-empty value, or
+  - Its FILETAGS contain :WIP:, or
+  - Any top-level heading contains the string \"WIP\" (case-insensitive)."
+  (when (file-exists-p file)
+    (with-temp-buffer
+      (insert-file-contents file)
+      (org-mode)
+      (let* ((case-fold-search t)
+             (keywords (org-collect-keywords '("WIP" "FILETAGS")))
+             (wip      (cadr (assoc "WIP" keywords)))
+             (filetags (cadr (assoc "FILETAGS" keywords))))
+        (or
+         (and wip (string-match-p "\\S-" wip))
+         (and filetags
+              (string-match-p ":WIP:" (concat ":" filetags ":")))
+         (save-excursion
+           (goto-char (point-min))
+           (re-search-forward "^\\*+ .*WIP.*" nil t)))))))
+
+
+(defun z/wip-sitemap (title list)
+  "Sitemap that lists only entries whose source files are WIP."
+  (let* ((root-dir "~/master-folder/org_files/org_web/") ;; adjust if needed
+         (items
+          (delq
+           nil
+           (mapcar
+            (lambda (entry)
+              (when (consp entry)
+                (let* ((link (car entry))
+                       ;; Extract relative filename from [[file:...]] link if present
+                       (filename (if (string-match "\\[\\[file:\\([^]]+\\)\\]" link)
+                                     (match-string 1 link)
+                                   link))
+                       (full-path (expand-file-name filename root-dir)))
+                  (when (z/wip-file-p full-path)
+                    (let* ((date (org-publish-find-date full-path org-publish-project-alist))
+                           (date-str (if date
+                                         (format-time-string "%d-%m-%Y %H:%M" date)
+                                       "")))
+                      (format "- %s @@html:<span class=\"post-date\">%s</span>@@"
+                              link date-str))))))
+            (cdr list)))))        ; skip sitemap root
+    (concat
+     "#+TITLE: " title "\n"
+     "#+OPTIONS: toc:nil num:nil\n\n"
+     "* Work in progress\n"
+     (if items
+         (mapconcat #'identity items "\n")
+       "No items currently marked as WIP.\n"))))
+
+
+
+
+(provide 'sitemaps)

lisp/tags.el

@@ -0,0 +1,85 @@
+(defun z/tag-slug (s)
+  "Turn a tag into a safe filename."
+  (let ((down (downcase s)))
+    (replace-regexp-in-string "[^a-z0-9]+" "-" down)))
+
+(defun z/collect-post-files ()
+  "Return all .org files from org-posts and org-blogs."
+  (let* ((expanded (org-publish-expand-projects org-publish-project-alist))
+         (posts    (assoc "org-posts" expanded))
+         (blogs    (assoc "org-blogs" expanded)))
+    (cl-remove-duplicates
+     (append (and posts (org-publish-get-base-files posts))
+             (and blogs (org-publish-get-base-files blogs)))
+     :test #'file-equal-p)))
+
+(defun z/gather-tag-index ()
+  "Return hash: tag -> list of (FILE TITLE DATE-ISO)."
+  (let ((idx (make-hash-table :test 'equal)))
+    (dolist (f (z/collect-post-files))
+      (when (and (string-match-p "\\.org\\'" f)
+                 (file-readable-p f)
+                 ;; ignore generated lists
+                 (not (member (file-name-nondirectory f)
+                              '("posts-list.org" "blogs-list.org" "sitemap.org" "categories.org"))))
+        (with-temp-buffer
+          (insert-file-contents f)
+          (org-mode)
+          (let* ((kw (org-collect-keywords '("TITLE" "FILETAGS" "TAGS" "DATE")))
+                 (title (or (car (cdr (assoc "TITLE" kw)))
+                            (file-name-base f)))
+                 (date  (or (car (cdr (assoc "DATE" kw))) "")) ;; optional
+                 (raw   (car (or (cdr (assoc "FILETAGS" kw))
+                                 (cdr (assoc "TAGS" kw))))))
+            (when raw
+              (dolist (tag (split-string raw ":" t))
+                (push (list f title date) (gethash tag idx))))))))
+    idx))
+
+(defun z/write-tag-pages ()
+  "Generate tags/*.org pages listing posts for each tag."
+  (let* ((site-root (expand-file-name "~/master-folder/org_files/org_web/"))
+         (tags-dir  (expand-file-name "tags" site-root)))
+    (unless (file-directory-p tags-dir)
+      (make-directory tags-dir t))
+    (let ((idx (z/gather-tag-index)))
+      (maphash
+       (lambda (tag items)
+         (let* ((slug (z/tag-slug tag))
+                (outfile (expand-file-name (format "%s.org" slug) tags-dir)))
+           (with-temp-file outfile
+             (insert (format "#+TITLE: Tag: %s\n#+OPTIONS: toc:nil num:nil title:nil \n\n* Posts tagged %s\n"
+                             tag tag))
+             ;; sort newest first if DATE present
+             (setq items (sort items (lambda (a b) (string> (nth 2 a) (nth 2 b)))))
+             (dolist (it items)
+               (let* ((file (nth 0 it))
+                      (title (nth 1 it))
+                      (rel   (file-relative-name file tags-dir)))
+                 ;; link to the source .org; org-publish will rewrite to the .html
+                 (insert (format "- [[file:%s][%s]]\n" rel title)))))))
+       idx)
+      )))
+
+(defun z/filetags-html (info)
+  "Return an HTML snippet for FILETAGS from INFO, or nil if none."
+  (let ((tags (plist-get info :filetags)))
+    (when tags
+      (format
+       "<div class=\"filetags\">%s</div>\n"
+       (mapconcat (lambda (tag)
+                    (format "<a href=\"/categories.html\"> <span class=\"post-tag\">%s</span> </a>" tag))
+                  tags " ")))))
+
+(defun z/insert-filetags-after-title (output backend info)
+  "Insert FILETAGS after the first <h1 class=\"title\"> in OUTPUT."
+  (if (org-export-derived-backend-p backend 'html)
+      (let ((block (z/filetags-html info)))
+        (if (and block
+                 (string-match "\\(<h1[^>]*class=[\"']title[\"'][^>]*>.*?</h1>\\)" output))
+            (replace-match (concat "\\1\n" block) t nil output)
+          output))
+    output))
+
+
+(provide 'tags)